Emacs

Hide .DS_Store file from Emacs

Emacs

.DS_StoreファイルをMacから削除する…というTipsは山ほどあるのですが、いづれもいつの間にかまた復活してしまいます。なので私の場合は、Emacsの各シーンで非表示になるように設定しています。

counsel

(setq counsel-find-file-ignore-regexp (regexp-opt '(".DS_Store")))

dired

;; omit .DS_Store
(require 'dired-x)
(setq-default dired-omit-files-p t)
(setq dired-omit-files "^\\.DS_Store")

neotree

;; Patched to allow everything but .DS_Store
;; Tips from https://github.com/syl20bnr/spacemacs/issues/2751
(with-eval-after-load 'neotree
  (defun neo-util--walk-dir (path)
    "Return the subdirectories and subfiles of the PATH."
    (let* ((full-path (neo-path--file-truename path)))
      (condition-case nil
	  (directory-files
	   path 'full "^\\([^.]\\|\\.[^D.][^S]\\).*")
	('file-error
	 (message "Walk directory %S failed." path)
	 nil)))))

view-modeを超えるhydra-pinkyの設定

Emacs

私のEmacs設定は、プログラマー masasamさんのブログ「 Solist Work Blog」から多くのことを吸収して日々成長しています。 そのブログの中にあるEmacs Pinkyをhydraで解決する の記事からhydra-pinkyの設定を参考にして更に使いやすくカスタマイズしてみました。

Screen Shot

hydra-pinky

hydra-pinky を発動するとミニバッファーに赤文字のメニューがでてきます。 hydra発動中はこの表示が続くのでわかりやすいです。 赤い表示のキーをタイプしている間はいつまでたってもhydraは解除されません。 hydraが終了する条件は、定義された赤いキー以外をタイプするか、青文字の “q”：quit を押した場合です。

つまりhydra-pinkyは、発動中はvew-modeに似た動作をし、そこから抜けると普通の編集モードに戻る…という仕組みです。 複雑なキーバインドを覚える必要もなくGUIでスピーディーにキー操作できるのはとてもありがたいです。 私自身はもともとブラインドタッチを使えないのでEmacs-pinkyの他にもいろいろhydraを活用しています。

HydraでEmacsのキーバインド問題を解消

sequential-command

rubikitch/sequential-command

Emacsを再起動して、C-a C-a C-aすると、行頭にいって、バッファーの頭にいって、元に戻る。 また、C-e C-e C-eすると行頭にいって、バッファーの頭にいって、元に戻るというシンプルな機能ですが、なにげに便利です。

pinkyでは、“a”,“e"キーに割り当てています。

window-toggle-division

Windowの縦分割、横分割をtoggleで切り替えします。

iflipb：バッファー移動

バッファー移動は、next-buffer previous-buffer を使ってもいいのですが、不要なbufferはignoreしてくれるfilipbを使います。 Emacs:タブを使わない究極のバッファー移動

矢印キーの扱い

Emacserの方から見ると邪道だと言われそうですが、私はカーソル移動に矢印キーを使うことも多いです。基本は、h,j,k,lを使うようにしていてもうっかり矢印キーに触れるとhydra-pinkyが消えてしまうので、pinky発動中は矢印関係の操作で消えないようにしています。

設定

;; sequential-command
(use-package sequential-command-config
  :commands sequential-command-setup-keys
  :hook (after-init . sequential-command-setup-keys))

;; other-window-or-split
(bind-key
 "C-q"
 (defun other-window-or-split ()
   "If there is one window, open split window.
If there are two or more windows, it will go to another window."
   (interactive)
   (when (one-window-p)
     (split-window-horizontally))
   (other-window 1)))

;; window-toggle-division
(defun window-toggle-division ()
  "Replace vertical <-> horizontal when divided into two."
  (interactive)
  (unless (= (count-windows 1) 2)
    (error "Not divided into two!"))
  (let ((before-height)
        (other-buf (window-buffer (next-window))))
    (setq before-height (window-height))
    (delete-other-windows)
    (if (= (window-height) before-height)
        (split-window-vertically)
      (split-window-horizontally))
    (other-window 1)
    (switch-to-buffer other-buf)
    (other-window -1)))

;; iflipb
(setq iflipb-wrap-around t)
(setq iflipb-ignore-buffers (list "^[*]" "^magit" "dir]$"))

;; Hydra-pinky
(bind-key [f11] 'hydra-pinky/body)
(key-chord-define-global
 "::"
 (defhydra hydra-pinky (:color red :hint nil)
   "
 ：_0_._1_._2_._3_._o_._S_._x_   ：_j_._k_._h_._l_._c_._a_._e_._b_._v_._SPC_._w_._s_._/_   ：_n_._p_._u_._t_   ：_<_-_:_-_>_   ：_q_uit"
   ;; window
   ("0" delete-window)
   ("1" delete-other-windows)
   ("2" split-window-below)
   ("3" split-window-right)
   ("o" other-window-or-split)
   ("S" window-swap-states)
   ("x" window-toggle-division)
   ;; page
   ("a" seq-home)
   ("e" seq-end)
   ("j" next-line)
   ("k" previous-line)
   ("l" forward-char)
   ("h" backward-char)
   ("c" recenter-top-bottom)
   ("<down>" next-line)
   ("<up>" previous-line)
   ("<right>" forward-char)
   ("<left>" backward-char)
   ("<C-up>" backward-paragraph)
   ("<C-down>" forward-paragraph)
   ("<C-left>" left-word)
   ("<C-right>" right-word)
   ("b" scroll-down-command)
   ("v" scroll-up-command)
   ("SPC" set-mark-command)
   ("w" avy-goto-word-1)
   ("s" swiper-isearch-region)
   ;; git
   ("n" git-gutter:next-hunk)
   ("p" git-gutter:previous-hunk)
   ("u" git-gutter:popup-hunk)
   ("t" git-gutter:toggle-popup-hunk)
   ;; buffer
   ("/" kill-buffer)
   (":" counsel-switch-buffer)
   ("<" iflipb-previous-buffer)
   (">" iflipb-next-buffer)
   ;; quit
   ("q" nil)))

neotreeを試してみる

Emacs

以下の機能を盛り込んで実用的なneotreeの設定を試してみました。

  1. アイコン表示（use all-the-icons）
  2. 文字サイズの変更（縮小）
  3. キーマップスタイルの変更（ワンキーで使う）
  4. ファイルオープン時にneotreeバッファーを隠す

NeoTree

設定

(use-package neotree
  :commands (neo-smart-open neo-create-file-auto-open)
  :init
  (setq-default neo-keymap-style 'concise)
  :config
  (setq neo-smart-open t)
  (setq neo-create-file-auto-open t)
  (setq neo-theme (if (display-graphic-p) 'icons 'arrow))
  (bind-key [f8] 'neotree-projectile-toggle)
  (bind-key "a" 'neotree-hidden-file-toggle neotree-mode-map)
  (bind-key "<left>" 'neotree-select-up-node neotree-mode-map))


;; Change neotree's font size
;; from https://github.com/jaypei/emacs-neotree/issues/218(setq-default neo-show-hidden-files t)
(defun neotree-text-scale ()
  "Text scale for neotree."
  (interactive)
  (text-scale-adjust 0)
  (text-scale-decrease 1)
  (message nil))
(add-hook 'neo-after-create-hook
	  (lambda (_)
	    (call-interactively 'neotree-text-scale)))


;; Hide neotree window after open file
;; from https://github.com/jaypei/emacs-neotree/issues/77
(add-hook 'neo-enter-hook
          (lambda (type & rest)
           (if (equal type 'file)
               (neotree-hide))))

swiper-region / swiper-isearch-region

Emacs

swiper/swiper-isearchをregion選択からも使えるようにするための設定。isearchではmigemoも使えるようにした。

(with-eval-after-load 'ivy' としているのは、(use-package avy-migemo-e.g.swiper)を遅延ロードさせてEmacsの起動時間を短縮するため。

設定

(defun swiper-isearch-region ()
  "If region is selected `swiper-isearch' with the keyword selected in region.
If the region isn't selected `swiper-isearch'."
  (interactive)
  (if (not (use-region-p))
      (swiper-isearch-migemo)
    (deactivate-mark)
    (swiper-isearch (buffer-substring-no-properties
		     (region-beginning) (region-end)))))

(defun swiper-region ()
  "If region is selected `swiper' with the keyword selected in region.
If the region isn't selected `swiper'."
  (interactive)
  (if (not (use-region-p))
      (swiper)
    (deactivate-mark)
    (swiper (buffer-substring-no-properties
	     (region-beginning) (region-end)))))

(with-eval-after-load 'ivy
  (use-package avy-migemo-e.g.swiper)
  (defun swiper-isearch-migemo ()
    "Using migemo with `swiper-iserach'."
    (interactive)
    (avy-migemo-mode 1)
    (swiper-isearch)
    (avy-migemo-mode 0)))

avy-migemo でエラー発生

avy、swiper、counsel の最近の仕様変更により関数名などが変わったため現状ではエラーが出るようになった。その対応のために下記のPRが出されているがまだマージされていないようなので、自分で差し替えて使っている。

direx-project + popwinで快適なディレクトリツリー環境を構築する

Emacs

Alt Text

Emacsでディレクトリツリーを表示させるパッケージにはいくつかの選択肢があります。neotreeが人気のようですが表示幅が自由にカスタマイズできないのでiconモードで使うとややストレスです。私は、direxが使いやすいので愛用しています。

例によってパッチワークですが、設定を公開します。特徴として以下の機能を持ちます。

  • フォルダー表示はビジュアルにしたいのでunicodeの絵文字を使う。
  • popwinを使うことで表示幅を自由に設定できる。(q または C−g で隠せる)
  • project内にいるなら、direx-projectを起動し、そうでなければ普通にdirexを起動する（これが気に入っています）
  • https://blog.shibayu36.org/entry/2013/02/12/191459

設定

;; direx
(use-package direx)
(setq direx:leaf-icon "  " direx:open-icon "📂" direx:closed-icon "📁")
(push '(direx:direx-mode :position left :width 35 :dedicated t)
      popwin:special-display-config)
;; use direx-project.el
;; https://blog.shibayu36.org/entry/2013/02/12/191459
(bind-key
 [f11]
 (defun direx:jump-to-project-directory ()
   "If in project, launch direx-project otherwise start direx."
  (interactive)
  (let ((result (ignore-errors
                  (direx-project:jump-to-project-root-other-window)
                  t)))
    (unless result
      (direx:jump-to-directory-other-window)))))

Emacs：複数のテーマを切り替えて使う

Emacs

Emacsを快適に使うためにいろいろ自分好みのテーマを模索します。私の場合、deeper-blue misterioso material と変遷し、今は doom-dracula を使っています。

それぞれ特徴がありコードを書く時、文章を書く時等々、その時々で気分転換を兼ねて切り替えて使えたら面白いと思ってググってみたところ下記サイトのQ&Aで面白いTipsを見つけたので試して見ました。結構快適で愉しいのでご紹介します。

設定

(setq my-themes (list 'doom-dracula 'material 'misterioso 'deeper-blue)) 
(setq curr-theme my-themes)
(defun my-theme-cycle ()
  "Cycle custom theme."
    (interactive)
    (disable-theme (car curr-theme)) 
    (setq curr-theme (cdr curr-theme))
    (if (null curr-theme) (setq curr-theme my-themes))
    (load-theme (car curr-theme) t)
    (message "%s" (car curr-theme)))
(global-set-key [f7] 'my-theme-cycle)
(setq curr-theme my-themes)
(load-theme (car curr-theme) t)

DashboardにQiitaの新着リスト（tag:emacs）を表示させる

Emacs

Alt Text

下記のTipsを参考にしてEmacsのDashboard画面にQiitaの新着一覧を表示させる事ができました。

設定

この設定例では、emacsタグで絞り込んだ一覧を表示するようにカスタマイズしています。

;; Use request.el for API call
(use-package request)

;; Item display function
(defun dashboard-qiita-insert-list (list-display-name list)
  "Render LIST-DISPLAY-NAME and items of LIST."
  (dashboard-insert-heading list-display-name)
  (mapc (lambda (el)
          (insert "\n    ")
          (widget-create 'push-button
                         :action `(lambda (&rest ignore)
                                    (browse-url ,(cdr (assoc 'url el))))
                         :mouse-face 'highlight
                         :follow-link "\C-m"
                         :button-prefix ""
                         :button-suffix ""
                         :format "%[%t%]"
                         (decode-coding-string (cdr (assoc 'title el)) 'utf-8))) list))

;; Function to get and display articles
(defun dashboard-qiita-insert (list-size)
  "Add the list of LIST-SIZE items from qiita."
  (request
   ;; (format "https://qiita.com/api/v2/items?page=1&per_page=%s" list-size)
   (format "https://qiita.com/api/v2/tags/emacs/items?page=1&per_page=%s" list-size)
   :sync t
   :parser 'json-read
   :success (cl-function
             (lambda (&key data &allow-other-keys)
               (dashboard-qiita-insert-list "Qiita(emacs-tag):" data)))))

;; add an article to the dashboard
(add-to-list 'dashboard-item-generators '(qiita . dashboard-qiita-insert))
(setq dashboard-items '((qiita . 15)))

参考

Emacs:Dashboardの詳細設定はGithubに公開しています。

Emacsのウインドウ操作の履歴をUndo/Redoする：winner-mode

Emacs

emacsでいろいろ作業していると意図しない形で勝手にウインドウズが分割されたりします。設定して “C-g” で隠せるものもありますが、それも出来ないときは、“C-x 0” や “C-x 1” のお世話になります。

(winner-mode)
(bind-key "C-<left>" 'winner-undo)
(bind-key "C-<right>" 'winner-redo)

(winner-mode)
(bind-key "C-c <left>" 'winner-undo)
(bind-key "C-c <right>" 'winner-redo)

Scratch bufferをKILLさせない：emacs-lock-mode

Emacs

わざわざscratch bufferをkillする人はいないと思いますが、“kill-other-windows” などを定義していると、うっかりscratchも一緒に消えてしまって困ることがありますね。

あやまってscratch killしたら新しいscratchを自動再生してくれるとか、kill出来ないようにする…というTipsも多いのですが、そんな回りくどいことをしなくてEmacsの標準機能だけて簡単に対応できることがわかりました。

emacs-lock-mode を使う##

パッケージも何もいりません。下記を設定してみてください。私は *Messages* も一緒に設定しています。

;; Set buffer that can not be killed.
(with-current-buffer "*scratch*"
  (emacs-lock-mode 'kill))
(with-current-buffer "*Messages*"
  (emacs-lock-mode 'kill))

この選定を有効にしたあとscratchをkill bufferしようとすると、

Buffer "*scratch*" is locked and cannot be killed

と叱られます。つまりkillされないようにロックが掛けられるのです。 emacs-lock-mode というのはもともとemacsの内蔵コマンドにあるのです。

Scratchを自動保存する

私もそうなのですが、ちょこっとした付箋的なメモをするためにscratchを使うという人も多いと思います。そんな人には、Emacsを再起動させても終了前のscratchが復帰してほしい…というニーズがあります。こうした目的のためのパッケージも何種類かありますが、私は、auto-seve-buffers-enhanced.el の機能を流用しています。このパッケージを使っているEmacserは多いと思うので、わざわざ専用のパッケージを使わずともscratchの保存再生が可能になります。

(use-package auto-save-buffers-enhanced)
;; Suppress Wrote's message
(setq auto-save-buffers-enhanced-quiet-save-p t)
;; Scratch buffer is also saved automatically
(setq auto-save-buffers-enhanced-save-scratch-buffer-to-file-p t)
(setq auto-save-buffers-enhanced-file-related-with-scratch-buffer "~/Dropbox/etc/emacs/scratch")
(auto-save-buffers-enhanced t)

scratchを瞬時にpopup表示させる

scratch-pop という便利なパッケージもあるのですが、私にとって余り必要と思わない機能もついているのでシンプルに設定を書いてみました。

popwinを導入した上で下記をinitファイルに書き、適当なキーバインドを設定すると一発でscratch bufferがpopupし、“C-g” で隠れてくれます。

(defun my:pop-scratch ()
  "Popup the scratch buffer."
  (interactive)
  (setq popwin:special-display-config '(("*scratch*")))
  (display-buffer "*scratch*"))

どんな使い方をしているか

簡単なelispの評価にscratchを使うのは当然ですが、私の場合、なにか調べたいキーワードをscratchにちょこっと書いてsearch-webで即検索…というような使い方を良くします。参考に私のhydra-search-webの設定にリンクを張っておきます。

Emacsからカレントディレクトリでターミナルアプリを開く

Emacs

私の場合は、Emacsからターミナル作業をするときは基本eshellを使うようにしています。ただ、ごくたまに別窓でターミナルアプリを立ち上げてemacsと併行して作業したいときがありますので以下のように設定しています。

当然ながらコマンドラインでアプリが起動できるようにbashなりzshなりで設定しておくことが前提です。

macのiterm.appを起動させる設定

;; Launch iterm.app with Current buffer
(defun my:iterm-app ()
  "Open iterm.app with current dir."
  (interactive)
  (let ((dir default-directory))
    (shell-command (concat "open -a iterm.app " dir))))